No Description

PKGBUILD 1.7KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061
  1. # $Id$
  2. # Maintainer: Gaetan Bisson <bisson@archlinux.org>
  3. # Contributor: Allan McRae <allan@archlinux.org>
  4. # Contributor: lydgate
  5. pkgname=mlocate
  6. pkgver=0.26.git.20170220
  7. _commit=c98bf6595703456558a6f9c163c746cdaa9e591f
  8. pkgrel=1
  9. pkgdesc='Merging locate/updatedb implementation'
  10. url='https://pagure.io/mlocate'
  11. arch=('x86_64')
  12. license=('GPL')
  13. backup=('etc/updatedb.conf')
  14. depends=('glibc')
  15. makedepends=('git')
  16. source=("git+https://pagure.io/mlocate.git#commit=$_commit"
  17. 'git://git.savannah.gnu.org/gnulib.git#commit=5861339993f3014cfad1b94fc7fe366fc2573598'
  18. 'sysusers.d'
  19. 'updatedb.conf'
  20. 'updatedb.cron')
  21. sha256sums=('SKIP'
  22. 'SKIP'
  23. '1713a8fc8b81f4a390bf8597c4c0e917474379002dcc984aad2f44218d10c82a'
  24. 'ea65bb68bb854803965ac16c770ba2567256e2066d68c272f1a1974ffc5c5ee7'
  25. '9f0c18a683f0dbeeae3f673bc3b2dbe1b54173da1589598672f254eb7a708f1e')
  26. prepare() {
  27. cd "${srcdir}/${pkgname}"
  28. sed -i '/^groupname /s/mlocate/locate/' Makefile.am
  29. ../gnulib/gnulib-tool --import # See file: ./HACKING
  30. autoreconf --install
  31. }
  32. build() {
  33. cd "${srcdir}/${pkgname}"
  34. ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var/lib
  35. make
  36. }
  37. check() {
  38. cd "${srcdir}/${pkgname}"
  39. make check
  40. }
  41. package() {
  42. cd "${srcdir}/${pkgname}"
  43. make DESTDIR="${pkgdir}" install
  44. chgrp 21 "${pkgdir}/usr/bin/locate"
  45. chmod 2755 "${pkgdir}/usr/bin/locate"
  46. ln -s locate "${pkgdir}/usr/bin/slocate"
  47. install -dm755 "${pkgdir}/var/lib"
  48. install -dm750 -g21 "${pkgdir}/var/lib/locate"
  49. install -Dm644 ../updatedb.conf "${pkgdir}/etc/updatedb.conf"
  50. install -Dm644 ../sysusers.d "${pkgdir}/usr/lib/sysusers.d/locate.conf"
  51. install -Dm744 ../updatedb.cron "${pkgdir}/etc/cron.daily/updatedb"
  52. }