[trunk] 'pangomm-2.42.0-1' modify

pangomm/trunk/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgbase=pangomm
+pkgname=(pangomm pangomm-docs)
+pkgver=2.42.0
+pkgrel=1
+pkgdesc="C++ bindings for Pango"
+url="https://www.gtkmm.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(pango glibmm cairomm)
+makedepends=(git mm-common glibmm-docs cairomm-docs)
+_commit=59f0ec837adc4fe02ea1c77965b880e1cfeeb4b9  # tags/2.42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/pangomm.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgbase
+  ./configure --prefix=/usr --enable-maintainer-mode
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package_pangomm() {
+  cd $pkgbase
+  sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
+  make DESTDIR="$pkgdir" install
+}
+
+package_pangomm-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  cd $pkgbase
+  make -C docs DESTDIR="$pkgdir" install
+}