[trunk] -> [staging] 'glade-3.38.0-1' add

glade/trunk/PKGBUILD

@@ -1,8 +1,8 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
 
 pkgname=glade
-pkgver=3.36.0+1+g3907987d
+pkgver=3.38.0
 pkgrel=1
 pkgdesc="User Interface Builder for GTK+ applications"
 url="https://glade.gnome.org/"
@@ -10,12 +10,12 @@ arch=(x86_64)
 license=(GPL LGPL)
 depends=(gtk3 libxml2)
 makedepends=(gtk-doc gobject-introspection python-gobject itstool docbook-xsl
-             git webkit2gtk meson)
+             git webkit2gtk meson gjs)
 checkdepends=(xorg-server-xvfb)
 optdepends=('devhelp: development help')
 groups=(gnome-extra)
 provides=(libgladeui-2.so)
-_commit=3907987d318875fae551ca9a2bce97f33749d230  # glade-3-36
+_commit=2e4875cbcf58d5f6aa4fde3c812ead4bf5eb44d6  # tags/GLADE_3_38_0^0
 source=("git+https://gitlab.gnome.org/GNOME/glade.git#commit=$_commit")
 sha256sums=('SKIP')
 
@@ -30,7 +30,7 @@ prepare() {
 
 build() {
   arch-meson $pkgname build -D gtk_doc=true
-  ninja -C build
+  meson compile -C build
 }
 
 check() {

glade/x86_64/staging/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
+
+pkgname=glade
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="User Interface Builder for GTK+ applications"
+url="https://glade.gnome.org/"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gtk3 libxml2)
+makedepends=(gtk-doc gobject-introspection python-gobject itstool docbook-xsl
+             git webkit2gtk meson gjs)
+checkdepends=(xorg-server-xvfb)
+optdepends=('devhelp: development help')
+groups=(gnome-extra)
+provides=(libgladeui-2.so)
+_commit=2e4875cbcf58d5f6aa4fde3c812ead4bf5eb44d6  # tags/GLADE_3_38_0^0
+source=("git+https://gitlab.gnome.org/GNOME/glade.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GLADE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}