Browse Source

[trunk] -> [extra] 'gtkmm3-3.24.1-1' add

master
artoo 2 years ago
parent
commit
7881a5a03d
Signed by: artoo GPG Key ID: 3292CD0BB0DB310B
  1. 46
      gtkmm3/repos/extra-x86_64/PKGBUILD

46
gtkmm3/repos/extra-x86_64/PKGBUILD

@ -0,0 +1,46 @@
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgbase=gtkmm3
pkgname=(gtkmm3 gtkmm3-docs)
pkgver=3.24.1
pkgrel=1
pkgdesc="C++ bindings for GTK+ 3"
url="http://www.gtkmm.org/"
arch=(x86_64)
license=(LGPL)
depends=(gtk3 pangomm atkmm)
makedepends=(git mm-common glibmm-docs cairomm-docs pangomm-docs atkmm-docs)
_commit=c04cd3340486698f75174965b071ccff10547a4b # tags/3.24.1^0
source=("git+https://gitlab.gnome.org/GNOME/gtkmm.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd gtkmm
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd gtkmm
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd gtkmm
./configure --prefix=/usr --enable-maintainer-mode
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package_gtkmm3() {
cd gtkmm
sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
make DESTDIR="$pkgdir" install
}
package_gtkmm3-docs() {
pkgdesc+=" (documentation)"
depends=()
cd gtkmm
make -C docs DESTDIR="$pkgdir" install
}
Loading…
Cancel
Save