You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

47 lines
1.2 KiB

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgbase=pygobject
pkgname=(python-gobject)
pkgver=3.42.0
pkgrel=3
pkgdesc="Python Bindings for GLib/GObject/GIO/GTK+"
url="https://wiki.gnome.org/Projects/PyGObject"
arch=(x86_64)
license=(LGPL)
depends=(gobject-introspection-runtime python)
makedepends=(python-cairo gobject-introspection git meson)
checkdepends=(python-pytest gtk3 xorg-server-xvfb)
optdepends=('cairo: Cairo bindings')
provides=("pygobject-devel=$pkgver")
conflicts=(pygobject-devel)
replaces=('pygobject-devel<=3.36.1-1')
_commit=d612f3cc675a1838bc5a18061df040ab6405fd31 # tags/3.42.0^0
source=("git+https://gitlab.gnome.org/GNOME/pygobject.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd pygobject
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd pygobject
}
build() {
artix-meson pygobject build
meson compile -C build
}
check() {
xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
}
package_python-gobject() {
meson install -C build --destdir "$pkgdir"
python -m compileall -d /usr/lib "$pkgdir/usr/lib"
python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
}
# vim:set sw=2 et: