You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

55 lines
1.3 KiB

# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>
pkgname=clutter
pkgver=1.26.4
pkgrel=1
pkgdesc="A toolkit for creating fast, portable, compelling dynamic UIs"
url="https://blogs.gnome.org/clutter/"
arch=(x86_64)
license=(LGPL)
depends=(gtk3 cogl libinput)
makedepends=(gobject-introspection gtk-doc git)
_commit=fd85623d34a54b3f5607011086cf19cb2c756a6a # tags/1.26.4^0
source=("git+https://gitlab.gnome.org/GNOME/clutter.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr \
--enable-introspection \
--enable-egl-backend \
--enable-gdk-backend \
--enable-wayland-backend \
--enable-x11-backend \
--enable-evdev-input \
--enable-wayland-compositor \
--enable-gtk-doc
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
depends+=(libcogl{,-pango,-path}.so)
provides+=(libclutter-1.0.so)
cd "$pkgname"
make DESTDIR="$pkgdir" install
}
# vim:set sw=2 et: