[trunk] -> [community-staging] 'cmus-2.10.0-3' add

trunk/PKGBUILD

@@ -6,7 +6,7 @@
 
 pkgname=cmus
 pkgver=2.10.0
-pkgrel=2
+pkgrel=3
 pkgdesc='Feature-rich ncurses-based music player'
 arch=('x86_64')
 url='https://cmus.github.io/'

x86_64/community-staging/PKGBUILD

@@ -0,0 +1,61 @@
+# Maintainer: Nathan Owens <ndowens@artixlinux.org>
+# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
+# Contributor: Aaron Griffin <aaron@archlinux.org>
+# Contributor: dorphell <dorphell@archlinux.org>
+# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
+
+pkgname=cmus
+pkgver=2.10.0
+pkgrel=3
+pkgdesc='Feature-rich ncurses-based music player'
+arch=('x86_64')
+url='https://cmus.github.io/'
+license=('GPL')
+depends=('libdiscid' 'ncurses')
+makedepends=(
+  'faad2'
+  'ffmpeg'
+  'flac'
+  'jack'
+  'libao'
+  'libcdio-paranoia'
+  'libmad'
+  'libmodplug'
+  'libmp4v2'
+  'libmpcdec'
+  'libpulse'
+  'libsamplerate'
+  'libvorbis'
+  'opusfile>=0.12'
+  'wavpack'
+)
+optdepends=('alsa-lib: for ALSA output plugin support'
+            'libao: for AO output plugin support'
+            'libpulse: for PulseAudio output plugin support'
+            'faad2: for AAC input plugin support'
+            'ffmpeg: for ffmpeg input plugin support'
+            'flac: for flac input plugin support'
+            'jack: for jack plugin support'
+            'libmad: for mp3 input plugin support'
+            'libmodplug: for modplug input plugin support'
+            'libmp4v2: for mp4 input plugin support'
+            'libmpcdec: for musepack input plugin support'
+            'libsamplerate: for sampe rate converter support'
+            'libvorbis: for vorbis input plugin support'
+            'libcdio-paranoia: for cdio support'
+            'opusfile: for opus input plugin support'
+            'wavpack: for wavpack input plugin support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/cmus/cmus/archive/v${pkgver}.tar.gz")
+sha256sums=('ff40068574810a7de3990f4f69c9c47ef49e37bd31d298d372e8bcdafb973fff')
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure prefix=/usr
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 contrib/_cmus "$pkgdir"/usr/share/zsh/site-functions/_cmus
+}