You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

37 lines
1.0 KiB

# Maintainer: artoo <artoo@artixlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
pkgname=dialog
pkgver=1.3_20220728
pkgrel=1
epoch=1
pkgdesc="A tool to display dialog boxes from shell scripts"
arch=('x86_64')
url="https://invisible-island.net/dialog/"
license=('LGPL2.1')
depends=('sh' 'ncurses')
provides=('libdialog.so')
source=(https://invisible-mirror.net/archives/$pkgname/$pkgname-${pkgver/_/-}.tgz{,.asc})
sha256sums=('54418973d559a461b00695fafe68df62f2bc73d506b436821d77ca3df454190b'
'SKIP')
validpgpkeys=('19882D92DDA4C400C22C0D56CC2AF4472167BE03') # Thomas E. Dickey (self-signed w/o SHA1) <dickey@invisible-island.net>
build() {
cd "$srcdir/$pkgname-${pkgver/_/-}"
./configure \
--prefix=/usr \
--enable-nls \
--with-libtool \
--with-ncursesw
make
}
package() {
cd "$srcdir/$pkgname-${pkgver/_/-}"
make DESTDIR="$pkgdir" install-full
}
# vim:set ts=2 sw=2 et: