You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

77 lines
2.0 KiB

# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
pkgname=haproxy
pkgver=2.5.7
pkgrel=1
pkgdesc='Reliable, high performance TCP/HTTP load balancer'
url='https://www.haproxy.org/'
arch=('x86_64')
license=('GPL')
depends=('openssl' 'pcre' 'zlib' 'libxcrypt' 'libcrypt.so' 'lua' 'systemd-libs')
makedepends=('systemd')
options=('debug')
backup=('etc/haproxy/haproxy.cfg')
install=haproxy.install
source=(https://www.haproxy.org/download/${pkgver%.*}/src/haproxy-$pkgver.tar.gz
haproxy.cfg
haproxy.sysusers
0001-Use-CFLAGS-and-LDFLAGS-when-building-admin.patch)
sha256sums=('e29f6334c6bdb521f63ddf335e2621bd2164503b99cf1f495b6f56ff9f3c164e'
'f6babef513b99a3fa0e50f2b144c73c980f1b78b119874ffa2580af1e651e7a9'
'b02b4088205039f0979aef0ef3e22957f493dd54eabefaee7011f2d795303b3e'
'8cdbb8be7a712f7b2c7f4823a96d2d2926d96b57632e9669069354d7f2df9fd2')
prepare() {
cd haproxy-$pkgver
patch -p1 <"$srcdir"/0001-Use-CFLAGS-and-LDFLAGS-when-building-admin.patch
}
build() {
cd haproxy-$pkgver
export CFLAGS="$CFLAGS -fwrapv"
make \
CFLAGS="$CFLAGS" \
LDFLAGS="$LDFLAGS" \
CPU=generic \
TARGET=linux-glibc \
USE_GETADDRINFO=1 \
USE_LUA=1 \
USE_OPENSSL=1 \
USE_PCRE=1 USE_PCRE_JIT=1 \
USE_PROMEX=1 \
USE_ZLIB=1
make \
SBINDIR=/usr/bin \
OPTIMIZE= \
CFLAGS="$CFLAGS" \
LDFLAGS="$LDFLAGS" \
admin/{halog/halog,iprange/ip{,6}range}
}
package() {
cd haproxy-$pkgver
make \
PREFIX="$pkgdir"/usr \
SBINDIR="$pkgdir"/usr/bin \
DOCDIR="$pkgdir"/usr/share/$pkgname \
install
for admin in admin/{halog/halog,iprange/ip{,6}range}; do
install -D -m0755 $admin "$pkgdir"/usr/bin/$(basename $admin)
done
install -D -m0644 ../haproxy.sysusers "$pkgdir"/usr/lib/sysusers.d/haproxy.conf
install -D -m0644 ../haproxy.cfg "$pkgdir"/etc/haproxy/haproxy.cfg
cp -r examples "$pkgdir"/usr/share/haproxy/examples
}