[trunk] -> [staging] 'python-asn1crypto-1.4.0-2' add

master
alium 2 years ago
parent 91f544cbba
commit 13aaf1223e
  1. 51
      x86_64/staging/PKGBUILD

@ -0,0 +1,51 @@
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
pkgbase=python-asn1crypto
pkgname=('python-asn1crypto' 'python2-asn1crypto')
pkgver=1.4.0
pkgrel=2
arch=('any')
license=('MIT')
pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
url="https://github.com/wbond/asn1crypto"
makedepends=('python-setuptools' 'python2-setuptools')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
sha512sums=('989e4e0650252c29477d71263549b99f2c51c87f0768c20264b3de65f32edd8e7922e8af23bb1a7e29567a4ad8c4c5d596cdf7db3c766352c7f19d4f93361cd0')
prepare() {
cp -a asn1crypto-$pkgver{,-py2}
}
build() {
cd "$srcdir"/asn1crypto-$pkgver
python setup.py build
cd "$srcdir"/asn1crypto-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/asn1crypto-$pkgver
python run.py tests
cd "$srcdir"/asn1crypto-$pkgver-py2
python2 run.py tests
}
package_python-asn1crypto() {
depends=('python')
cd asn1crypto-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
}
package_python2-asn1crypto() {
depends=('python2')
cd asn1crypto-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python2-asn1crypto/LICENSE
}
Loading…
Cancel
Save