[trunk] -> [community] 'python-asn1crypto-1.2.0-1' add

repos/community-any/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
+
+pkgbase=python-asn1crypto
+pkgname=('python-asn1crypto' 'python2-asn1crypto')
+pkgver=1.2.0
+pkgrel=1
+arch=('any')
+license=('MIT')
+pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
+url="https://github.com/wbond/asn1crypto"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
+sha512sums=('00d7d67e717fde9651aacc35141b872e4fcb6c46457af5e971aceae7f9acf1d018dfef94eddfa05eac7c7f3a4c768edc8a1ca0474101c1e77ee377aa4771274b')
+
+prepare() {
+  cp -a asn1crypto-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python run.py tests
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 run.py tests
+}
+
+package_python-asn1crypto() {
+  depends=('python')
+
+  cd asn1crypto-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
+}
+
+package_python2-asn1crypto() {
+  depends=('python2')
+
+  cd asn1crypto-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python2-asn1crypto/LICENSE
+}

trunk/PKGBUILD

@@ -1,19 +1,18 @@
-# $Id$
 # Maintainer: Felix Yan <felixonmars@archlinux.org>
 # Contributor: Ionut Biru <ibiru@archlinux.org>
 # Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
 
 pkgbase=python-asn1crypto
 pkgname=('python-asn1crypto' 'python2-asn1crypto')
-pkgver=0.24.0
-pkgrel=2
+pkgver=1.2.0
+pkgrel=1
 arch=('any')
 license=('MIT')
 pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
 url="https://github.com/wbond/asn1crypto"
 makedepends=('python-setuptools' 'python2-setuptools')
 source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
-sha512sums=('426cc380903b4dd7aadd7b831e3a11ee3442c961a33b856d4aa8d9060e829f2e0ad905a60c4d6504569718fe2cee01d9be31628c89ef030bc34281e381c898e8')
+sha512sums=('00d7d67e717fde9651aacc35141b872e4fcb6c46457af5e971aceae7f9acf1d018dfef94eddfa05eac7c7f3a4c768edc8a1ca0474101c1e77ee377aa4771274b')
 
 prepare() {
   cp -a asn1crypto-$pkgver{,-py2}