You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

53 lines
1.7 KiB

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Morten Linderud <foxboron@archlinux.org>
pkgname=rclone
pkgver=1.53.4
pkgrel=1
pkgdesc="Sync files to and from Google Drive, S3, Swift, Cloudfiles, Dropbox and Google Cloud Storage"
arch=('x86_64')
url="https://rclone.org/"
license=('MIT')
depends=('glibc')
optdepends=('fuse2: for rclone mount')
makedepends=('python' 'pandoc' 'go' 'git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/rclone/rclone/archive/v$pkgver.tar.gz")
sha512sums=('df36c8e51a39762f2edf0a8acfba081252c9006ffa3190f0eec6341e6a052a4d9078e1df7f59db3d9e35ce48cd0a23343d2d66106dd90656821fff5526f0c404')
prepare() {
cd "rclone-$pkgver"
sed -i "1s/python$/&2/" bin/make_manual.py bin/make_backend_docs.py
}
build() {
cd "rclone-$pkgver"
export GOFLAGS="-buildmode=pie -trimpath"
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
PATH=".:$PATH" make TAG=v$pkgver rclone rclone.1 MANUAL.html MANUAL.txt
./rclone genautocomplete bash rclone.bash_completion
./rclone genautocomplete zsh rclone.zsh_completion
}
check() {
cd "rclone-$pkgver"
make TAG=v$pkgver test
}
package() {
cd "rclone-$pkgver"
install -Dm755 rclone "$pkgdir"/usr/bin/rclone
install -Dm644 rclone.bash_completion "$pkgdir"/usr/share/bash-completion/completions/rclone
install -Dm644 rclone.zsh_completion "$pkgdir"/usr/share/zsh/site-functions/_rclone
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
install -Dm644 rclone.1 "$pkgdir"/usr/share/man/man1/rclone.1
install -d "$pkgdir"/usr/share/doc/$pkgname
install -t "$pkgdir"/usr/share/doc/$pkgname -m644 MANUAL.html MANUAL.txt
}