You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

33 lines
1.1 KiB

# Maintainer: Nathan Owens <ndowens@artixlinux.org>
pkgname=sdl2_image
pkgver=2.6.2
pkgrel=2
pkgdesc="A simple library to load images of various formats as SDL surfaces (Version 2)"
arch=('x86_64')
url="https://github.com/libsdl-org/SDL_image"
license=('MIT')
depends=('sdl2' 'libpng' 'libtiff' 'libjpeg' 'libwebp' 'libavif' 'libjxl')
makedepends=('cmake')
source=("https://github.com/libsdl-org/SDL_image/releases/download/release-${pkgver}/SDL2_image-${pkgver}.tar.gz"{,.sig})
sha512sums=('b2bcd54c90bd76d12af41bbfc5bfaa5fcba42fe4adcb3587568af8ee74c4e7a4d7d3606638d0668974224e648db9b7267b76b067362cf59e98551547905f46f7'
'SKIP')
validpgpkeys=('1528635D8053A57F77D1E08630A59377A7763BE6')
build() {
cd "${srcdir}/SDL2_image-${pkgver}/"
./configure --disable-static --prefix=/usr \
--disable-jpg-shared \
--disable-png-shared \
--disable-stb-image \
--disable-tif-shared \
--disable-jxl-shared \
--disable-webp-shared
make
}
package() {
cd "${srcdir}/SDL2_image-${pkgver}/"
make DESTDIR="${pkgdir}/" install
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}