[trunk] -> [extra] 'sof-bin-1.8-1' add

master
Nathan Owens 1 year ago
parent f60f39d5b2
commit 69828907f6
  1. 42
      x86_64/extra/PKGBUILD

@ -0,0 +1,42 @@
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
pkgbase=sof-bin
pkgname=(sof-firmware sof-tools)
pkgver=1.8
pkgrel=1
pkgdesc="Sound Open Firmware"
url="https://www.sofproject.org/"
arch=(x86_64)
license=(custom:BSD custom:ISC)
makedepends=(rsync)
source=(https://github.com/thesofproject/$pkgbase/releases/download/v$pkgver/$pkgbase-v$pkgver.tar.gz)
sha256sums=('cc9ed7b24a892c8b16ac95e0f12d3d6ddab1d71758060c73d1296803dc4e8cff')
package_sof-firmware() {
options=(!strip)
cd $pkgbase-v$pkgver
(
export FW_DEST="$pkgdir/usr/lib/firmware/intel"
export TOOLS_DEST="$srcdir/tools/usr/bin"
mkdir -p "$FW_DEST" "$TOOLS_DEST"
./install.sh v$pkgver
)
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
}
package_sof-tools() {
pkgdesc+=" - tools"
depends=(alsa-lib)
cd $pkgbase-v$pkgver
mv "$srcdir"/tools/* "$pkgdir"
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
}
# vim:set sw=2 et:
Loading…
Cancel
Save