Browse Source

[trunk] -> [testing] 'zbar-0.23.1-9' add

master
artoo 8 months ago
parent
commit
af0a1f9446
  1. 47
      x86_64/testing/PKGBUILD

47
x86_64/testing/PKGBUILD

@ -0,0 +1,47 @@
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Marti Raudsepp <marti@juffo.org>
# Contributor: Radu Andries <admiral0@tuxfamily.org>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
pkgname=zbar
pkgver=0.23.1
pkgrel=9
pkgdesc="Application and library for reading bar codes from various sources"
arch=('x86_64')
url="https://github.com/mchehab/zbar"
license=('LGPL')
depends=('dbus' 'imagemagick' 'libsm' 'libxv' 'v4l-utils')
makedepends=('gtk3' 'qt5-x11extras' 'python' 'xmlto' 'docbook-xsl' 'gobject-introspection')
optdepends=('gtk3: for zbar-gtk'
'qt5-x11extras: for zbar-qt'
'python: for zbar python bindings')
conflicts=('zbar-gtk' 'zbar-qt' 'python-zbar')
provides=('zbar-gtk' 'zbar-qt' 'python-zbar')
replaces=('zbar-gtk' 'zbar-qt' 'python-zbar')
source=("$pkgname-$pkgver.tar.gz::https://github.com/mchehab/zbar/archive/$pkgver.tar.gz"
zbar-autoconf-2.70.patch::"https://github.com/mchehab/zbar/commit/89e7900d.patch")
sha512sums=('ae7741cf750a10cf53dc11abcd482c3885507153ee37f6e3364ed5ed72184ebb009560b8c40d8090603a551fb681700a962838a59ce77d005d080ee49fbfa54b'
'db0006724bb1a51e432c6daa02bef1093886a382db055f00b4d641d28a1ff130425a7e4ff419a97a141b0d012306b12a3aff4f72df1b52a00549d91f9b457094')
prepare() {
cd zbar-$pkgver
patch -p1 -i ../zbar-autoconf-2.70.patch # Fix build with autoconf 2.70
autoreconf -vfi
# Removed in Python 3.9. Ignored in Python 3.0+ anyway.
sed -i '/tp_print/d' python/enum.c
}
build() {
cd zbar-$pkgver
./configure --prefix=/usr --with-qt --with-gtk=gtk3 --with-dbusconfdir=/usr/share CFLAGS="$CFLAGS -DNDEBUG"
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd zbar-$pkgver
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
Loading…
Cancel
Save